The type of CFF hinting used for this text. Use CFFHinting constants for this property. This property applies only if the RenderingMode property of the text is set to RenderingMode.CFF.

The type of CFF (Compact Font Format) hinting used determines whether the Flash runtime forces strong horizontal stems to fit to a sub-pixel grid or not.

Applies only to embedded fonts.

The default value is CFFHinting.HORIZONTAL_STEM.

For the CFFHinting property, you can use the following constants from the CFFHinting class:

See also

Specifies how the font should be looked up.

The default value is FontLookup.DEVICE.

To set values for this property, use the following string values:

See also

The name of the font to use, or a comma-separated list of font names. The runtime renders the element with the first available font in the list. For example "Arial, Helvetica, _sans" causes the player to search for Arial, then Helvetica, if Arial is not found, then _sans, if neither is found.

Flash runtimes support three generic device font names: _sans (for sans serif fonts), _serif (for serif fonts), and _typewriter (for mono-space fonts). These are mapped to specific device fonts depending on the platform.

The default value is "_serif".

Flash runtimes provide font fallback for glyphs which are not found in the selected font. Whether the font in use is embedded or device, if the glyph is not found in the font, the runtime attempts to render it using another device font likely to contain the glyph.

See also

Specifies the font posture.

The default value is FontPosture.NORMAL.

To set values for this property, use the following constants from the FontPosture class:

See also

Specifies the font weight.

The default value is FontWeight.NORMAL.

To set values for this property, use the following constants from the FontWeight class:

See also

Indicates whether or not the FontDescription is locked. If true the FontDescription cannot be modified. Call FontDescription.clone() to get an unlocked copy of the FontDescription object.

The rendering mode used for this text. Use RenderingMode constants for this property.

Applies only to embedded fonts.

The default value is RenderingMode.CFF.

To set values for this property, use the following constants from the RenderingMode class:

See also

Creates a FontDescription object.

Constructs an unlocked, cloned copy of the FontDescription.

This example creates a FontDescription object, assigns a device font to it, sets various font properties, and assigns the new object (and therefore locking it) to an ElementFormat object. A new TextElement is created, using the ElementFormat, and the TextElement is used as content for a TextBlock. A line of text is created from the TextBlock.

To modify the FontDescription object, first check its locked property. If true, use the clone() method to create an unlocked copy of the FontDescription, change its properties, and assign it to a new ElementFormat object. Then re-link the new ElementFormat to the TextBlock. When the lines are re-broken, the new lines will have the new font settings.

package {

    import flash.display.Sprite;
	import flash.text.engine.*;

	
	public class FontDescription_cloneExample extends Sprite {
		private var fd:FontDescription;
		private var fd2:FontDescription;
		
		public function FontDescription_cloneExample():void {
			fd = new FontDescription();
			fd.fontLookup = flash.text.engine.FontLookup.DEVICE;
			fd.fontName = "Palatino";
			fd.fontWeight = flash.text.engine.FontWeight.BOLD;
			fd.fontPosture = flash.text.engine.FontPosture.ITALIC;

			var ef1:ElementFormat = new ElementFormat(fd);
			
			var str:String = "This is flash text 0123456789";
			var tb:TextBlock = new TextBlock();
			var te1:TextElement = new TextElement(str, ef1);
			tb.content = te1;
			var line1:TextLine = tb.createTextLine(null, 600);
			addChild(line1);
			
			fd2 = (fd.locked) ? fd.clone() : fd;	
			fd2.fontWeight = flash.text.engine.FontWeight.NORMAL;
			var ef2:ElementFormat = new ElementFormat(fd2);

			tb.content.elementFormat=ef2;
			var line2:TextLine = tb.createTextLine(null, 600);
			addChild(line2);
			
		}
	}	
}

Creates a FontDescription object using font data loaded dynamically from a file.

Returns true if a usable device font is available with the specified fontName, fontWeight, and fontPosture.

The flash.text.engine classes can only use OpenType and TrueType device fonts. If a font based on an older font technology is used, the runtime falls back to known good device fonts on a glyph-by-glyph basis to render the text

See also

Returns true if an embedded font is available with the specified fontName, fontWeight, and fontPosture where Font.fontType is flash.text.FontType.EMBEDDED_CFF. Starting with Flash Player 10, two kinds of embedded fonts can appear in application content. Normal embedded fonts are only used by TextField. CFF embedded fonts are only used by the flash.text.engine classes. The two types are distinguised by the fontType property of the Font class, as returned by the enumerateFonts() function.

The flash.text.engine classes cannot use a font of type EMBEDDED. If fontLookup is set to FontLookup.EMBEDDED_CFF and the only font available at run time with the specified name, weight, and posture is of type EMBEDDED, the runtime falls back to device fonts on a glyph-by-glyph basis to render the text, as if no embedded font were available with the specified name and style.

If both EMBEDDED and EMBEDDED_CFF fonts are available with the same name, weight, and posture, the EMBEDDED_CFF font is selected and text renders with the EMBEDDED_CFF font.

See also

This example creates a FontDescription object, assigns a device font to it, sets various font properties, and assigns the new object to an ElementFormat object. Additional font formatting is done within ElementFormat. A new TextElement is created, using the ElementFormat, and the TextElement is used as content for a TextBlock. A line of text is created from the TextBlock.

package {

    import flash.display.Sprite;
	import flash.text.engine.*;

	
	public class FontDescriptionExample extends Sprite {
		
		public function FontDescriptionExample():void {
			var fd:FontDescription = new FontDescription();
			fd.fontLookup = flash.text.engine.FontLookup.DEVICE;
			fd.fontName = "Palatino";
			fd.fontWeight = flash.text.engine.FontWeight.BOLD;
			fd.fontPosture = flash.text.engine.FontPosture.ITALIC;

			var ef1:ElementFormat = new ElementFormat(fd);
			ef1.fontSize = 30;
			ef1.color = 0xFF0000;
			
			var str:String = "This is flash text 0123456789";
			var tb:TextBlock = new TextBlock();
			var te1:TextElement = new TextElement(str, ef1);
			tb.content = te1;
			var line1:TextLine = tb.createTextLine(null, 600);
			addChild(line1);
			
		}
	}	
}