package  {
    
	import flash.display.Sprite;
	import flash.display.Shape;
	import flash.display.BitmapData;
	import flash.display.GraphicsPath;
	import flash.ui.MouseCursorData;
	import flash.ui.Mouse;
	import flash.geom.Matrix;	
	
	public class MouseCursorDataExample extends Sprite {
		//Graphics path data for an arrow
		private var cursorPoints:Vector.<Number> = new <Number>[0,8, 16,8, 16,0, 24,12, 16,24, 16,16, 0,16, 0,8];
		private var cursorDrawCommands:Vector.<int> = new <int>[1,2,2,2,2,2,2,2];
		
		public function MouseCursorDataExample() {
			var mouseCursorData:MouseCursorData = new MouseCursorData();
			mouseCursorData.data = makeCursorImages();
			mouseCursorData.frameRate = 1;
			
			Mouse.registerCursor( "spinningArrow", mouseCursorData );
			Mouse.cursor = "spinningArrow";
		}
		
		//Returns a Vector containing 8 cursor images
		private function makeCursorImages():Vector.<BitmapData>
		{
			var cursorData:Vector.<BitmapData> = new Vector.<BitmapData>();
			
			var cursorShape:Shape = new Shape();
			cursorShape.graphics.beginFill( 0xff5555, .75 );
			cursorShape.graphics.lineStyle( 1 );
			cursorShape.graphics.drawPath( cursorDrawCommands, cursorPoints );
			cursorShape.graphics.endFill();
			var transformer:Matrix = new Matrix();
			
			//Rotate and draw the arrow shape to a BitmapData object for each of 8 frames 
			for( var i:int = 0; i < 8; i++ )
			{
				var cursorFrame:BitmapData = new BitmapData( 32, 32, true, 0 );
				cursorFrame.draw( cursorShape, transformer );
				cursorData.push( cursorFrame );
				
				transformer.translate(-15,-15);
				transformer.rotate( 0.785398163 );
				transformer.translate(15,15);
			}
			return cursorData;
		}
	}
	
}