Specifies the alpha transparency value to use for out-of-bounds displacements. It is specified as a normalized value from 0.0 to 1.0. For example, .25 sets a transparency value of 25%. The default value is 0. Use this property if the mode property is set to DisplacementMapFilterMode.COLOR.

Specifies what color to use for out-of-bounds displacements. The valid range of displacements is 0.0 to 1.0. Values are in hexadecimal format. The default value for color is 0. Use this property if the mode property is set to DisplacementMapFilterMode.COLOR.

Describes which color channel to use in the map image to displace the x result. Possible values are BitmapDataChannel constants:

• BitmapDataChannel.ALPHA
• BitmapDataChannel.BLUE
• BitmapDataChannel.GREEN
• BitmapDataChannel.RED

See also

Describes which color channel to use in the map image to displace the y result. Possible values are BitmapDataChannel constants:

• BitmapDataChannel.ALPHA
• BitmapDataChannel.BLUE
• BitmapDataChannel.GREEN
• BitmapDataChannel.RED

See also

A BitmapData object containing the displacement map data.

See also

A value that contains the offset of the upper-left corner of the target display object from the upper-left corner of the map image.

See also

The mode for the filter. Possible values are DisplacementMapFilterMode constants:

• DisplacementMapFilterMode.WRAP — Wraps the displacement value to the other side of the source image.
• DisplacementMapFilterMode.CLAMP — Clamps the displacement value to the edge of the source image.
• DisplacementMapFilterMode.IGNORE — If the displacement value is out of range, ignores the displacement and uses the source pixel.
• DisplacementMapFilterMode.COLOR — If the displacement value is outside the image, substitutes the values in the color and alpha properties.

See also

The multiplier to use to scale the x displacement result from the map calculation.

The multiplier to use to scale the y displacement result from the map calculation.

Initializes a DisplacementMapFilter instance with the specified parameters.

See also

Returns a copy of this filter object.

1. The class defines variables for the background color, for the text field label, and for the size and offset that will be used in various functions.
2. The constructor function calls the draw() method, which uses the methods of the Graphics class to draw a square with a radial gradient fill. Note that graphics is a property of the DisplacementMapFilterExample object, which extends Sprite.
3. The constructor function calls the createLabel() method, which creates a text field displaying the value of labelText and adds it to the display list.
4. The constructor function calls the createFilter() method, which does the following:
   • Creates a variable named filter for the filter object.
   • Calls the getDisplacementMapFilter() method and assigns its return value to the filter variable.
   • Passes filter to the filters property of the DisplacementFilterExample object (the main class).
5. The getBitmapFilter() method creates a BitmapData object named mapBitmap and assigns it the results of the createBitmapData() method. The mapBitmap object, along with other variables, defines a new displacement map filter.
6. The createBitmapData() method creates a new BitmapData object that is based on the current contents of the DisplacementMapFilterExample object. It creates a new bitmap based on bitmapData and adds the bitmap to the Stage.

package {
    import flash.display.Bitmap;
    import flash.display.BitmapData;
    import flash.display.BitmapDataChannel;
    import flash.display.GradientType;
    import flash.display.SpreadMethod;
    import flash.display.Sprite;
    import flash.filters.BitmapFilter;
    import flash.filters.DisplacementMapFilter;
    import flash.filters.DisplacementMapFilterMode;
    import flash.geom.Matrix;
    import flash.geom.Point;
    import flash.text.TextField;
    
    public class DisplacementMapFilterExample extends Sprite {
        private var bgColor:uint     = 0xFFCC00;
        private var size:uint        = 200;
        private var offset:uint      = 90;
        private var labelText:String = "Watch the text bend with the displacement map";

        public function DisplacementMapFilterExample() {
            draw();
            createLabel();
            createFilter();
        }

        private function createFilter():void {
            var filter:BitmapFilter = getBitmapFilter();
            filters = new Array(filter);
        }

        private function getBitmapFilter():BitmapFilter {
            var mapBitmap:BitmapData = createBitmapData();
            var mapPoint:Point       = new Point(0, 0);
            var channels:uint        = BitmapDataChannel.RED;
            var componentX:uint      = channels;
            var componentY:uint      = channels;
            var scaleX:Number        = 0.5;
            var scaleY:Number        = -30;
            var mode:String          = DisplacementMapFilterMode.CLAMP;
            var color:uint           = 0;
            var alpha:Number         = 0;
            return new DisplacementMapFilter(mapBitmap,
                                             mapPoint,
                                             componentX,
                                             componentY,
                                             scaleX,
                                             scaleY,
                                             mode,
                                             color,
                                             alpha);
        }

        private function draw():void {
            var matrix:Matrix = new Matrix();
            matrix.createGradientBox(size, size);
            graphics.beginGradientFill(GradientType.RADIAL,
                                       [0xFF0000, 0x0000FF],
                                       [100, 100],
                                       [55, 200],
                                       matrix,
                                       SpreadMethod.PAD);
            graphics.drawRect(0, 0, size, size);
        }

        private function createBitmapData():BitmapData {
            var bitmapData:BitmapData = new BitmapData(size, size, true, bgColor);
            bitmapData.draw(this, new Matrix());
            var bitmap:Bitmap = new Bitmap(bitmapData);
            bitmap.x = size;
            addChild(bitmap);
            return bitmapData;
        }

        private function createLabel():void {
            var tf:TextField = new TextField();
            tf.text = labelText;
            tf.y = offset;
            tf.width = size;
            addChild(tf);
        }
    }
}