Controls the rendering of advanced anti-aliased text. The visual quality of text is very subjective, and while Flash Player tries to use the best settings for various conditions, designers may choose a different look or feel for their text. Also, using displayMode allows a designer to override Flash Player's subpixel choice and create visual consistency independent of the user's hardware. Use the values in the TextDisplayMode class to set this property.

The default value is "default".

See also

The adaptively sampled distance fields (ADFs) quality level for advanced anti-aliasing. The only acceptable values are 3, 4, and 7.

Advanced anti-aliasing uses ADFs to represent the outlines that determine a glyph. The higher the quality, the more cache space is required for ADF structures. A value of 3 takes the least amount of memory and provides the lowest quality. Larger fonts require more cache space; at a font size of 64 pixels, the quality level increases from 3 to 4 or from 4 to 7 unless, the level is already set to 7.

The default value is 4.

Sets a custom continuous stroke modulation (CSM) lookup table for a font. Flash Player attempts to detect the best CSM for your font. If you are not satisfied with the CSM that the Flash Player provides, you can customize your own CSM by using the setAdvancedAntiAliasingTable() method.

See also

1. Place the Georgia font, named georgia.ttf in the same directory as this AS file.
2. Add the following lines directly underneath the class definition:
3. [Embed(source="georgia.ttf", fontFamily="Georgia")]
4. private var embeddedFont:String;

1. Place a text field on the stage and select it.
2. In the Property Inspector, set that text field's font to Georgia
3. In the Property Inspector, press "Embed..." and select "All"

Notes:

• You will need to compile the SWF file with "Local playback security" set to "Access local files only".

package {
	import flash.display.DisplayObject;
	import flash.display.Sprite;
	import flash.events.*;
	import flash.text.*;
	
	public class TextRendererExample2 extends Sprite {

		private var gutter:int = 10;

		public function TextRendererExample2() {
			createTextField(8,AntiAliasType.NORMAL);
			createTextField(8,AntiAliasType.ADVANCED);
			createTextField(24,AntiAliasType.NORMAL);
			createTextField(24,AntiAliasType.ADVANCED);
		}
			
		private function createTextField(fontSize:Number,antiAliasType:String):TextField {
			var tf:TextField = new TextField();
		    tf.embedFonts = true;
			tf.autoSize = TextFieldAutoSize.LEFT;
			tf.antiAliasType = antiAliasType;
		    tf.defaultTextFormat = getTextFormat(fontSize);
		    tf.selectable = false;
		    tf.mouseEnabled = true;
			tf.text = "The quick brown fox jumped over the lazy dog.";
        	if(numChildren > 0) {
        		var sibling:DisplayObject = getChildAt(numChildren - 1);
        		tf.y = sibling.y + sibling.height + gutter;
	        }
	        addChild(tf);
		    return tf;
		}
		
		private function getTextFormat(fontSize:Number):TextFormat {
		    var format:TextFormat = new TextFormat();
		    format.size = fontSize;
		    format.font = "Georgia";
		    return format;
		}
	}
}