Indicates whether the Alt key is active (true) or inactive (false). Supported for Windows only. On other operating systems, this property is always set to false.

Indicates whether the primary mouse button is pressed (true) or not (false).

Indicates whether or not the mouse down event is part of a multi-click sequence. This parameter will be zero for all mouse events other than MouseEvent.mouseDown, MouseEvent.mouseUp, MouseEvent.middleMouseDown, MouseEvent.middleMouseUp, MouseEvent.rightMouseDown, and MouseEvent.rightMouseUp. Listening for single clicks, double clicks, or any multi-click sequence is possible with the clickCount parameter. For example, an initial MouseEvent.mouseDown and MouseEvent.mouseUp will have a clickCount of 1, and the second MouseEvent.mouseDown and MouseEvent.mouseUp in a double-click sequence will have a clickCount of 2. If the mouse moves sufficiently or the multi-click sequence is interrupted for some reason, then the next MouseEvent.mouseDown will have a clickCount of 1. The doubleClick event will continue to fire as expected.

Indicates whether the command key is activated (Mac only.)

The value of property commandKey will have the same value as property ctrlKey on the Mac. Always false on Windows or Linux.

Indicates whether the Control key is activated on Mac and whether the Ctrl key is activated on Windows or Linux.

On Windows or Linux, indicates whether the Ctrl key is active (true) or inactive (false). On Macintosh, indicates whether either the Control key or the Command key is activated.

Indicates how many lines should be scrolled for each unit the user rotates the mouse wheel. A positive delta value indicates an upward scroll; a negative value indicates a downward scroll. Typical values are 1 to 3, but faster rotation may produce larger values. This setting depends on the device and operating system and is usually configurable by the user. This property applies only to the MouseEvent.mouseWheel event.

If true, the relatedObject property is set to null for reasons related to security sandboxes. If the nominal value of relatedObject is a reference to a DisplayObject in another sandbox, relatedObject is set to null unless there is permission in both directions across this sandbox boundary. Permission is established by calling Security.allowDomain() from a SWF file, or by providing a policy file from the server of an image file, and setting the LoaderContext.checkPolicyFile property when loading the image.

See also

When mouse locking is disabled, the horizontal coordinate at which the event occurred relative to the containing sprite. Disable mouse locking by setting Stage.mouseLock to false.

When mouse locking is enabled, localX and localY are 0. Use movementX and movementY to determine the changes to mouse position when mouse locking is enabled.

See also

When mouse locking is disabled, the vertical coordinate at which the event occurred relative to the containing sprite. Disable mouse locking by setting Stage.mouseLock to false.

When mouse locking is enabled, localX and localY are 0. Use movementX and movementY to determine the changes to mouse position when mouse locking is enabled.

See also

When mouse locking is enabled, the change in mouse position in the X direction since the last mouse event. Enable mouse locking by setting Stage.mouseLock to true.

When mouse locking is enabled:

• localX and localY contain 0.
• movementX and movementY contain delta values.
• movementX and movementY are never transformed based on stage transformation. That means they always remain in screen coordinates.

movementX and movementY are 0 when Stage.mouseLock is false.

See also

When mouse locking is enabled, the change in mouse position in the Y direction since the last mouse event. Enable mouse locking by setting Stage.mouseLock to true.

When mouse locking is enabled:

• localX and localY contain 0.
• movementX and movementY contain delta values.
• movementX and movementY are never transformed based on stage transformation. That means they always remain in screen coordinates.

movementX and movementY are 0 when Stage.mouseLock is false.

See also

A reference to a display list object that is related to the event. For example, when a mouseOut event occurs, relatedObject represents the display list object to which the pointing device now points. This property applies to the mouseOut, mouseOver, rollOut, and rollOver events.

The value of this property can be null in two circumstances: if there no related object, or there is a related object, but it is in a security sandbox to which you don't have access. Use the isRelatedObjectInaccessible() property to determine which of these reasons applies.

See also

Indicates whether the Shift key is active (true) or inactive (false).

The horizontal coordinate at which the event occurred in global Stage coordinates. This property is calculated when the localX property is set.

The vertical coordinate at which the event occurred in global Stage coordinates. This property is calculated when the localY property is set.

Creates an Event object that contains information about mouse events. Event objects are passed as parameters to event listeners.

Creates a copy of the MouseEvent object and sets the value of each property to match that of the original.

Returns a string that contains all the properties of the MouseEvent object. The string is in the following format:

[MouseEvent type=value bubbles=value cancelable=value ... delta=value]

Instructs Flash Player or Adobe AIR to render after processing of this event completes, if the display list has been modified.

Defines the value of the type property of a click event object.

This event has the following properties:

See also

The MouseEvent.CONTEXT_MENU constant defines the value of the type property of a contextMenu event object.

This event has the following properties:

Defines the value of the type property of a doubleClick event object. The doubleClickEnabled property must be true for an object to generate the doubleClick event.

This event has the following properties:

See also

Defines the value of the type property of a middleClick event object.

This event has the following properties:

See also

Defines the value of the type property of a middleMouseDown event object.

This event has the following properties:

See also

Defines the value of the type property of a middleMouseUp event object.

This event has the following properties:

See also

Defines the value of the type property of a mouseDown event object.

This event has the following properties:

See also

Defines the value of the type property of a mouseMove event object.

This event has the following properties:

See also

In the constructor, a rectangle innerRect Sprite object is created and the line style is set to green. The line style for drawing on the MouseEvent_MOUSE_MOVEExample Sprite container is set to red. Separate event listeners for the MouseEvent.MOUSE_UP and MouseEvent.MOUSE_DOWN events are added for the application's main Sprite object and innerRect Sprite object. In both cases, the mouse down event listener methods move the current drawing position to the mouse pointer's location and add a listener for the MouseEvent.MOUSE_MOVE event. When the mouse pointer is moved, the invoked event listener methods follows the pointer and draw a line using the graphics.LineTo() method. (Note: The innerRect Sprite object obscures the red lines of the main Sprite object that are drawn behind the rectangle.) When the MouseEvent.MOUSE_UP event occurs, the listener for the MOUSE_MOVE event is removed and drawing is stopped.

package {
    import flash.display.Sprite;
	import flash.display.Graphics;
	import flash.events.MouseEvent;

	public class MouseEvent_MOUSE_MOVEExample extends Sprite {
		private var innerRect:Sprite = new Sprite();
		
		public function MouseEvent_MOUSE_MOVEExample() {

			graphics.lineStyle(3, 0xFF0000, 1);
			stage.addEventListener(MouseEvent.MOUSE_DOWN, mouseDownHandler);
			stage.addEventListener(MouseEvent.MOUSE_UP, mouseUpHandler);

			innerRect.graphics.lineStyle(1, 0x00FF00, 1);
			innerRect.graphics.beginFill(0xFFFFFF);
			innerRect.graphics.drawRect(10, 10, 200, 200);
			innerRect.graphics.endFill();
			innerRect.addEventListener(MouseEvent.MOUSE_DOWN, innerRectMouseDownHandler);
			innerRect.addEventListener(MouseEvent.MOUSE_UP, innerRectMouseUpHandler);
			addChild(innerRect);
		}

		private function mouseDownHandler(event:MouseEvent):void {
			graphics.moveTo(event.stageX, event.stageY);
			stage.addEventListener(MouseEvent.MOUSE_MOVE, mouseMoveHandler);
		}
	
		private function mouseMoveHandler(event:MouseEvent):void {
			graphics.lineTo(event.stageX, event.stageY);
		}	
	
		private function mouseUpHandler(event:MouseEvent):void {
			stage.removeEventListener(MouseEvent.MOUSE_MOVE, mouseMoveHandler);
		}

		private function innerRectMouseDownHandler(event:MouseEvent):void {
			innerRect.graphics.moveTo(event.localX, event.localY);
			innerRect.addEventListener(MouseEvent.MOUSE_MOVE, innerRectMouseMoveHandler);
		}
	
		private function innerRectMouseMoveHandler(event:MouseEvent):void {
			innerRect.graphics.lineTo(event.localX, event.localY);
		}	
	
		private function innerRectMouseUpHandler(event:MouseEvent):void {
			innerRect.removeEventListener(MouseEvent.MOUSE_MOVE, innerRectMouseMoveHandler);
		}
	}
}

Defines the value of the type property of a mouseOut event object.

This event has the following properties:

See also

Defines the value of the type property of a mouseOver event object.

This event has the following properties:

See also

Defines the value of the type property of a mouseUp event object.

This event has the following properties:

See also

Defines the value of the type property of a mouseWheel event object.

This event has the following properties:

See also

Defines the value of the type property of a mouseWheelHorizontal event object.

This event has the following properties:

See also

Defines the value of the type property of a releaseOutside event object.

This event has the following properties:

See also

Defines the value of the type property of a rightClick event object.

This event has the following properties:

See also

Defines the value of the type property of a rightMouseDown event object.

This event has the following properties:

See also

Defines the value of the type property of a rightMouseUp event object.

This event has the following properties:

See also

Defines the value of the type property of a rollOut event object.

This event has the following properties:

See also

Defines the value of the type property of a rollOver event object.

This event has the following properties:

See also

1. The example declares properties for the size (100 x 100 pixels) and the background color (orange) for later use in drawing the square.
2. The constructor creates a new ChildSprite object child. Its constructor first draws an orange 100 x 100 pixel square at coordinates (0,0) by calling its draw() method and then adds seven event listeners/subscribers.
   • click/clickHandler(): Dispatched when the user single-clicks with the left mouse button over the square.
   • doubleClick/doubleClickHandler(): Dispatched when the user double-clicks the left mouse button over the square.
   • mouseDown/mouseDownHandler(): When the ChildSprite object (the orange square) is clicked, a trace() message is printed to the screen, and then ChildSprite.draw() is called, which draws a dark yellow square in place of the light blue one drawn in mouseOverHandler(). The mouseDownHandler() method also adds a mouseMoveevent listener and the mouseMoveHandler() subscriber (described below), which processes the mouse moves. Then the startDrag() method is called, which allows the Sprite object to be dragged.
   • mouseOut/mouseOutHandler(): Dispatched whenever the pointer leaves the square area. The draw() method is called to return the square to its normal size and color.
   • mouseOver/mouseOverHandler(): Dispatched when the mouse pointer is over the square. This method redraws the square so that it is larger and its background color is dark yellow.
   • mouseUp/mouseUpHandler(): When the user releases the mouse button, the mouseMove event listener is removed and stopDrag is called, which freezes the square in place.
   • mouseMove/mouseMoveHandler(): Called as part of the mouseDownHandler() function, and dispatched when the user is pressing the left mouse button and dragging the square.
   • mouseWheel/mouseWheelHandler(): Dispatched when the user rotates the mouse wheel over the square.
3. The ChildSprite instance child is then added to the display list by means of addChild(), which promptly draws the orange square.

Notes:

• The MouseEventExample class should be the document root.
• Some of the event methods listed above declare a local variable sprite, which is assigned the cast of event.target to type Sprite.

package {
	import flash.display.Sprite;

	public class MouseEventExample extends Sprite {
		private var size:uint = 100;
		private var bgColor:uint = 0xFFCC00;

		public function MouseEventExample() {
			var child:ChildSprite = new ChildSprite();
			addChild(child);
		}
	}
}

import flash.display.Sprite;
import flash.events.MouseEvent;

class ChildSprite extends Sprite {
	private var size:uint = 50;
	private var overSize:uint = 60;
	private var backgroundColor:uint = 0xFFCC00;
	private var overColor:uint = 0xCCFF00;
	private var downColor:uint = 0x00CCFF;

	public function ChildSprite() {
		draw(size, size, backgroundColor);
            doubleClickEnabled = true;
		addEventListener(MouseEvent.CLICK, clickHandler);
		addEventListener(MouseEvent.DOUBLE_CLICK, doubleClickHandler);
		addEventListener(MouseEvent.MOUSE_DOWN, mouseDownHandler);
		addEventListener(MouseEvent.MOUSE_OUT, mouseOutHandler);
		addEventListener(MouseEvent.MOUSE_OVER, mouseOverHandler);
		addEventListener(MouseEvent.MOUSE_UP, mouseUpHandler);
		addEventListener(MouseEvent.MOUSE_WHEEL, mouseWheelHandler);
	}

	private function draw(w:uint, h:uint, bgColor:uint):void {
		graphics.clear();
		graphics.beginFill(bgColor);
		graphics.drawRect(0, 0, w, h);
		graphics.endFill();
	}

	private function clickHandler(event:MouseEvent):void {
		trace("clickHandler");
	}

	private function doubleClickHandler(event:MouseEvent):void {
		trace("doubleClickHandler");
	}

	private function mouseDownHandler(event:MouseEvent):void {
		trace("mouseDownHandler");
		draw(overSize, overSize, downColor);

		var sprite:Sprite = Sprite(event.target);
		sprite.addEventListener(MouseEvent.MOUSE_MOVE, mouseMoveHandler);
		sprite.startDrag();
	}

	private function mouseMoveHandler(event:MouseEvent):void {
		trace("mouseMoveHandler");
		event.updateAfterEvent();
	}

	private function mouseOutHandler(event:MouseEvent):void {
		trace("mouseOutHandler");
		draw(size, size, backgroundColor);
	}

	private function mouseOverHandler(event:MouseEvent):void {
		trace("mouseOverHandler");
		draw(overSize, overSize, overColor);
	}

	private function mouseWheelHandler(event:MouseEvent):void {
		trace("mouseWheelHandler delta: " + event.delta);
	}

	private function mouseUpHandler(event:MouseEvent):void {
		trace("mouseUpHandler");
		var sprite:Sprite = Sprite(event.target);
		sprite.removeEventListener(MouseEvent.MOUSE_MOVE, mouseMoveHandler);
		sprite.stopDrag();
		draw(overSize, overSize, overColor);
	}
}