An instance of the ContextMenuBuiltInItems class with the following properties: forwardAndBack, loop, play, print, quality, rewind, save, and zoom. Setting these properties to false removes the corresponding menu items from the specified ContextMenu object. These properties are enumerable and are set to true by default.

Note: In AIR, context menus do not have built-in items.

See also

An instance of the ContextMenuClipboardItems class with the following properties: cut, copy, paste, delete, selectAll. Setting one of these properties to false disables the corresponding item in the clipboard menu.

See also

package {
    import flash.ui.ContextMenu;
    import flash.events.ContextMenuEvent;
    import flash.display.Sprite;

    public class ContextMenuClipboardItemsExample extends Sprite {
        public function ContextMenuClipboardItemsExample() {
            var myContextMenu:ContextMenu = new ContextMenu();
            myContextMenu.clipboardMenu = true;
            myContextMenu.addEventListener(ContextMenuEvent.MENU_SELECT, menuSelectHandler);
            var rc:Sprite = new Sprite();
            rc.graphics.beginFill(0xDDDDDD);
            rc.graphics.drawRect(0,0,100,30);
            addChild(rc);
            rc.contextMenu = myContextMenu;
        }
        function menuSelectHandler(event:ContextMenuEvent):void {
            event.contextMenuOwner.contextMenu.clipboardItems.copy = true;
            event.contextMenuOwner.contextMenu.clipboardItems.paste = true;
        }
    }
}

Specifies whether or not the clipboard menu should be used. If this value is true, the clipboardItems property determines which items are enabled or disabled on the clipboard menu.

If the link property is non-null, this clipBoardMenu property is ignored.

An array of ContextMenuItem objects. Each object in the array represents a context menu item that you have defined. Use this property to add, remove, or modify these custom menu items.

To add new menu items, you create a ContextMenuItem object and then add it to the customItems array (for example, by using Array.push()). For more information about creating menu items, see the ContextMenuItem class entry.

See also

The isSupported property is set to true if the ContextMenu class is supported on the current platform, otherwise it is set to false.

The array of custom items in this menu.

Using this property is equivalent to using the customItems property. The array is sorted in display order.

The URLRequest of the link. If this property is null, a normal context menu is displayed. If this property is not null, the link context menu is displayed, and operates on the url specified.

If a link is specified, the clipboardMenu property is ignored.

The default value is null.

The number of items in this menu.

Creates a ContextMenu object.

See also

Adds a menu item at the bottom of the menu.

When creating a context menu, you can add either NativeMenuItem or ContextMenuItem objects. However, it is advisable to use only one type of object in a context menu so that all items in the menu have the same properties.

Creates a copy of the specified ContextMenu object. The copy inherits all the properties of the original menu object.

Reports whether this menu contains the specified menu item.

Pops up this menu at the specified location.

Note: In Flash Player, this method is not supported.

Gets the menu item at the specified index.

Gets the position of the specified item.

Hides all built-in menu items (except Settings) in the specified ContextMenu object. If the debugger version of Flash Player is running, the Debugging menu item appears, although it is dimmed for SWF files that do not have remote debugging enabled.

This method hides only menu items that appear in the standard context menu; it does not affect items that appear in the edit and error menus.

This method works by setting all the Boolean members of my_cm.builtInItems to false. You can selectively make a built-in item visible by setting its corresponding member in my_cm.builtInItems to true.

Note: In AIR, context menus do not have built-in items. Calling this method will have no effect.

See also

Removes all items from the menu.

Removes and returns the menu item at the specified index.

Dispatched when a user first generates a context menu but before the contents of the context menu are displayed. This allows your program to modify the set of context menu items before displaying the menu. The user generates the context menu by right-clicking the pointing device.

Defines the value of the type property of a menuSelect event object.

This event has the following properties:

1. A property myContextMenu is declared and then assigned to a new ContextMenu object and a property redRectangle of type Sprite is declared.
2. The method removeDefaultItems() is called, which removes all built-in context menu items except Print.
3. The method addCustomMenuItems() is called, which places a menu item called Red to Black menu selection into the defaultItems array by using the push() method of Array. A menuItemSelect event listener is added to the ContextMenuItem object and the associated method is called menuItemSelectHandler(). This method prints out some statements using trace() whenever the context menu is accessed and Red to Black is selected. Also the red square is removed and replaced with a black one.
4. An event listener of type menuSelect is added, along with the associated method menuSelectHandler, which simply prints out three statements using trace() every time an item in the context menu is opened.
5. Then addChildren() draws a red square and adds it to the display list, where it is immediately displayed.
6. Finally, myContextMenu is assigned to the context menu of the redRectangle sprite so that the custom context menu is displayed only when the mouse pointer is over the square.

package {
	import flash.ui.ContextMenu;
	import flash.ui.ContextMenuItem;
	import flash.ui.ContextMenuBuiltInItems;
	import flash.events.ContextMenuEvent;
	import flash.display.Sprite;
	import flash.display.Shape;
    import flash.text.TextField;

	public class ContextMenuExample extends Sprite {
		private var myContextMenu:ContextMenu;
		private var menuLabel:String = "Reverse Colors";
		private var textLabel:String = "Right Click";
		private var redRectangle:Sprite;
		private var label:TextField;
		private var size:uint = 100;
		private var black:uint = 0x000000;
		private var red:uint = 0xFF0000;

		public function ContextMenuExample() {
			myContextMenu = new ContextMenu();
			removeDefaultItems();
			addCustomMenuItems();
			myContextMenu.addEventListener(ContextMenuEvent.MENU_SELECT, menuSelectHandler);

			addChildren();
			redRectangle.contextMenu = myContextMenu;
		}

		private function addChildren():void {
			redRectangle = new Sprite();
			redRectangle.graphics.beginFill(red);
			redRectangle.graphics.drawRect(0, 0, size, size);
			addChild(redRectangle);
			redRectangle.x = size;
			redRectangle.y = size;
			label = createLabel();
			redRectangle.addChild(label);
		}

		private function removeDefaultItems():void {
			myContextMenu.hideBuiltInItems();
			var defaultItems:ContextMenuBuiltInItems = myContextMenu.builtInItems;
			defaultItems.print = true;
		}

		private function addCustomMenuItems():void {
			var item:ContextMenuItem = new ContextMenuItem(menuLabel);
			myContextMenu.customItems.push(item);
			item.addEventListener(ContextMenuEvent.MENU_ITEM_SELECT, menuItemSelectHandler);
		}

		private function menuSelectHandler(event:ContextMenuEvent):void {
			trace("menuSelectHandler: " + event);
		}

		private function menuItemSelectHandler(event:ContextMenuEvent):void {
			trace("menuItemSelectHandler: " + event);
			var textColor:uint = (label.textColor == black) ? red : black;
			var bgColor:uint = (label.textColor == black) ? black : red;
			redRectangle.graphics.clear();
			redRectangle.graphics.beginFill(bgColor);
			redRectangle.graphics.drawRect(0, 0, size, size);
			label.textColor = textColor;
		}

		private function createLabel():TextField {
			var txtField:TextField = new TextField();
			txtField.text = textLabel;
			return txtField;
		}
	}
}