flash.system.ApplicationDomain (ActionScript 3.0)

	Property	Defined by
		constructor : Object A reference to the class object or constructor function for a given object instance.	Object
		currentDomain : ApplicationDomain [static][read-only] Gets the current application domain in which your code is executing.	ApplicationDomain
		domainMemory : ByteArray Gets and sets the object on which domain-global memory operations will operate within this ApplicationDomain.	ApplicationDomain
		MIN_DOMAIN_MEMORY_LENGTH : uint [static][read-only] Gets the minimum memory object length required to be used as ApplicationDomain.domainMemory.	ApplicationDomain
		parentDomain : ApplicationDomain [read-only] Gets the parent domain of this application domain.	ApplicationDomain
		prototype : Object [static] A reference to the prototype object of a class or function object.	Object

	Method	Defined by
		ApplicationDomain(parentDomain:ApplicationDomain = null) Creates a new application domain.	ApplicationDomain
		getDefinition(name:String):Object Gets a public definition from the specified application domain.	ApplicationDomain
		getQualifiedDefinitionNames():Vector.<String> Gets all fully-qualified names of public definitions from the specified application domain.	ApplicationDomain
		hasDefinition(name:String):Boolean Checks to see if a public definition exists within the specified application domain.	ApplicationDomain
		hasOwnProperty(name:String):Boolean Indicates whether an object has a specified property defined.	Object
		isPrototypeOf(theClass:Object):Boolean Indicates whether an instance of the Object class is in the prototype chain of the object specified as the parameter.	Object
		propertyIsEnumerable(name:String):Boolean Indicates whether the specified property exists and is enumerable.	Object
		setPropertyIsEnumerable(name:String, isEnum:Boolean = true):void Sets the availability of a dynamic property for loop operations.	Object
		toLocaleString():String Returns the string representation of this object, formatted according to locale-specific conventions.	Object
		toString():String Returns the string representation of the specified object.	Object
		valueOf():Object Returns the primitive value of the specified object.	Object

Property detail

currentDomain

property

currentDomain:ApplicationDomain [read-only]

Language version:

ActionScript 3.0

Runtime version:

Gets the current application domain in which your code is executing.

Implementation
public static function get currentDomain():ApplicationDomain

domainMemory

property

domainMemory:ByteArray [read-write]

Language version:

ActionScript 3.0

Runtime version:

AIR 1.5

Gets and sets the object on which domain-global memory operations will operate within this ApplicationDomain.

Implementation
public function get domainMemory():ByteArray
public function set domainMemory(value:ByteArray):void

MIN_DOMAIN_MEMORY_LENGTH

property

MIN_DOMAIN_MEMORY_LENGTH:uint [read-only]

Language version:

ActionScript 3.0

Runtime version:

AIR 1.5

Gets the minimum memory object length required to be used as ApplicationDomain.domainMemory.

Implementation
public static function get MIN_DOMAIN_MEMORY_LENGTH():uint

parentDomain

property

parentDomain:ApplicationDomain [read-only]

Language version:

ActionScript 3.0

Runtime version:

Gets the parent domain of this application domain.

Implementation
public function get parentDomain():ApplicationDomain

Constructor detail

ApplicationDomain

()

constructor

public function ApplicationDomain(parentDomain:ApplicationDomain = null)

Language version:

ActionScript 3.0

Runtime version:

Creates a new application domain.

Parameters

parentDomain:ApplicationDomain (default = null) — If no parent domain is passed in, this application domain takes the system domain as its parent.

Method detail

getDefinition

()

method

public function getDefinition(name:String):Object

Language version:

ActionScript 3.0

Runtime version:

Gets a public definition from the specified application domain. The definition can be that of a class, a namespace, or a function.

Parameters

name:String — The name of the definition.

Returns

Object — The object associated with the definition.

Throws

ReferenceError — No public definition exists with the specified name.

getQualifiedDefinitionNames

()

method

public function getQualifiedDefinitionNames():Vector.<String>

Language version:

ActionScript 3.0

Runtime version:

AIR 3.3

Gets all fully-qualified names of public definitions from the specified application domain. The definition can be that of a class, a namespace, or a function. The names returned from this method can be passed to the getDefinition() method to get the object of the actual definition.

The returned Vector is of type String, where each String is in the form: package.path::definitionName

If definitionName is in the top-level package, then package.path:: is omitted.

For example, for the following class definition:

     package my.Example
     {
       public class SampleClass extends Sprite
       { }
     }

This method returns "my.Example::SampleClass".

Returns

Vector.<String> — An unsorted Vector of Strings which are the names of the definitions. If there is no definition, an empty Vector.<String> is returned.

Throws

SecurityError — The definition belongs to a domain to which the calling code does not have access.

hasDefinition

()

method

public function hasDefinition(name:String):Boolean

Language version:

ActionScript 3.0

Runtime version:

Checks to see if a public definition exists within the specified application domain. The definition can be that of a class, a namespace, or a function.

Parameters

name:String — The name of the definition.

Returns

Boolean — A value of true if the specified definition exists; otherwise, false.

Examples

examples\ApplicationDomainExample

The following example demonstrates runtime class loading as well as how to call public methods of a class that reside in another SWF.

Notes:

Since the ClassLoader class loads a SWF file, local security needs to be at the file system level.
To run this example, you must have a swf file called RuntimeClasses.swf existing in the same folder as the ApplicationDomainExample.swf file.

Begin by creating the RuntimeClasses.swf file from the following code:

  package {
    import flash.display.Sprite;
 
    public class RuntimeClasses extends Sprite
    {
      public function RuntimeClasses()
      {}
       
      public function greet():String {
        return("Hello World");
      }
    }
  }

Then implement the following code:


package {
    import flash.display.DisplayObject;
    import flash.display.Sprite;
    import flash.errors.IllegalOperationError;
    import flash.events.Event;
    import flash.text.TextField;

    public class ApplicationDomainExample extends Sprite {
        private var loader:ClassLoader;
        private var tf:TextField = new TextField();

        public function ApplicationDomainExample() {
            addChild(tf);

            loader = new ClassLoader();
            loader.addEventListener(ClassLoader.LOAD_ERROR,loadErrorHandler);
            loader.addEventListener(ClassLoader.CLASS_LOADED,classLoadedHandler);
            loader.load("RuntimeClasses.swf");
        }

        private function loadErrorHandler(e:Event):void {
            tf.text = "Load failed";
            throw new IllegalOperationError("Cannot load the specified file.");
        }

        private function classLoadedHandler(e:Event):void {
            var runtimeClassRef:Class = loader.getClass("RuntimeClasses");
            var greeter:Object = new runtimeClassRef();

            tf.text = greeter.greet();
        }
    }
}

import flash.display.Loader;
import flash.errors.IllegalOperationError;
import flash.events.Event;
import flash.events.EventDispatcher;
import flash.events.IOErrorEvent;
import flash.events.SecurityErrorEvent;
import flash.net.URLRequest;
import flash.system.ApplicationDomain;
import flash.system.LoaderContext;

class ClassLoader extends EventDispatcher {
    public static var CLASS_LOADED:String = "classLoaded";
    public static var LOAD_ERROR:String = "loadError";
    private var loader:Loader;
    private var swfLib:String;
    private var request:URLRequest;
    private var loadedClass:Class;

    public function ClassLoader() {

        loader = new Loader();
        loader.contentLoaderInfo.addEventListener(Event.COMPLETE,completeHandler);
        loader.contentLoaderInfo.addEventListener(IOErrorEvent.IO_ERROR,ioErrorHandler);
        loader.contentLoaderInfo.addEventListener(SecurityErrorEvent.SECURITY_ERROR,securityErrorHandler);
    }

    public function load(lib:String):void {
        swfLib = lib;
        request = new URLRequest(swfLib);
        var context:LoaderContext = new LoaderContext();
        context.applicationDomain=ApplicationDomain.currentDomain;
        loader.load(request,context);
    }

    public function getClass(className:String):Class {
        try {
            return loader.contentLoaderInfo.applicationDomain.getDefinition(className)  as  Class;
        } catch (e:Error) {
            throw new IllegalOperationError(className + " definition not found in " + swfLib);
        }
        return null;
    }

    private function completeHandler(e:Event):void {
        dispatchEvent(new Event(ClassLoader.CLASS_LOADED));
    }

    private function ioErrorHandler(e:Event):void {
        dispatchEvent(new Event(ClassLoader.LOAD_ERROR));
    }

    private function securityErrorHandler(e:Event):void {
        dispatchEvent(new Event(ClassLoader.LOAD_ERROR));
    }
}

examples\ApplicationDomainExample.2

If multiple SWF files contain compiled classes with the same name but provide different implementation, you can partition the classes of externally loaded SWF files separate from the classes of each other following this example. Previously, the child SWF was instructed to use ApplicationDomain.currentDomain. In this case, a new ApplicationDomain is created, so that then the properties and methods of the Greeter class of whichever SWF loads second will not replace the properties and methods of the first Greeter class. You can test this by modifying the context.applicationDomain property in the load method of ClassLoader.

Notes:

Since the ClassLoader class loads a SWF file, local security needs to be at the file system level.
To run this example, you must have two SWF files called Greeter.swf existing in an "en" and "es" folder respectively.

Create a Greeter.as file in the "en" directory with the following code:

  package {
     import flash.display.Sprite;
 
 	public class Greeter extends Sprite
 	{
 		public function Greeter()
 		{
 		}
 		
 		public function greet():String {
 			return("Good Morning");
 		}
 	}
  }

Then create a very similar Greeter.as file in the "es" directory:

  package {
 	import flash.display.Sprite;
 
 	public class Greeter extends Sprite
 	{
 		public function Greeter()
 		{
 		}
 		
 		public function greet():String {
 			return("Buenos Dias");
 		}
 	}
 }

Compile SWF files for both and then implement the following code:

package {
	import flash.display.DisplayObject;
	import flash.display.Sprite;
	import flash.errors.IllegalOperationError;
	import flash.events.Event;
	import flash.text.TextField;
	import flash.text.TextFieldAutoSize;

	public class ApplicationDomainExample2 extends Sprite {
		private var spanishGreeterLoader:ClassLoader;
		private var englishGreeterLoader:ClassLoader;
		private var tf:TextField = new TextField();
		private var greetersLoaded:uint = 0;

		public function ApplicationDomainExample2() {
			tf.autoSize = TextFieldAutoSize.LEFT;
			addChild(tf);

			spanishGreeterLoader = new ClassLoader();
			spanishGreeterLoader.addEventListener(ClassLoader.LOAD_ERROR,loadErrorHandler);
			spanishGreeterLoader.addEventListener(ClassLoader.CLASS_LOADED,classLoadedHandler);
			spanishGreeterLoader.load("es/Greeter.swf");
			
			englishGreeterLoader = new ClassLoader();
			englishGreeterLoader.addEventListener(ClassLoader.LOAD_ERROR,loadErrorHandler);
			englishGreeterLoader.addEventListener(ClassLoader.CLASS_LOADED,classLoadedHandler);
			englishGreeterLoader.load("en/Greeter.swf");
		}

		private function loadErrorHandler(e:Event):void {
			tf.text = "Load failed";
			throw new IllegalOperationError("Cannot load the specified file.");
		}

		private function classLoadedHandler(e:Event):void {
			greetersLoaded++;
			if(greetersLoaded == 2) {
				greet();	
			}
		}
		
		private function greet():void {
			var spanishGreeter:Class = spanishGreeterLoader.getClass("Greeter");
			var englishGreeter:Class = englishGreeterLoader.getClass("Greeter");
			var greeter1 = new spanishGreeter();
			var greeter2 = new englishGreeter();
			
			tf.text = greeter1.greet() + "\n" + greeter2.greet();
		}
	}
}

import flash.display.Loader;
import flash.errors.IllegalOperationError;
import flash.events.Event;
import flash.events.EventDispatcher;
import flash.events.IOErrorEvent;
import flash.events.SecurityErrorEvent;
import flash.net.URLRequest;
import flash.system.ApplicationDomain;
import flash.system.LoaderContext;

class ClassLoader extends EventDispatcher {
	public static var CLASS_LOADED:String = "classLoaded";
	public static var LOAD_ERROR:String = "loadError";
	private var loader:Loader;
	private var swfLib:String;
	private var request:URLRequest;
	private var loadedClass:Class;

	public function ClassLoader() {

		loader = new Loader();
		loader.contentLoaderInfo.addEventListener(Event.COMPLETE,completeHandler);
		loader.contentLoaderInfo.addEventListener(IOErrorEvent.IO_ERROR,ioErrorHandler);
		loader.contentLoaderInfo.addEventListener(SecurityErrorEvent.SECURITY_ERROR,securityErrorHandler);
	}

	public function load(lib:String):void {
		swfLib = lib;
		request = new URLRequest(swfLib);
		var context:LoaderContext = new LoaderContext();
//		context.applicationDomain = ApplicationDomain.currentDomain;
		context.applicationDomain = new ApplicationDomain();
		loader.load(request,context);
	}

	public function getClass(className:String):Class {
		try {
			return loader.contentLoaderInfo.applicationDomain.getDefinition(className)  as  Class;
		} catch (e:Error) {
			throw new IllegalOperationError(className + " definition not found in " + swfLib);
		}
		return null;
	}

	private function completeHandler(e:Event):void {
		dispatchEvent(new Event(ClassLoader.CLASS_LOADED));
	}

	private function ioErrorHandler(e:Event):void {
		dispatchEvent(new Event(ClassLoader.LOAD_ERROR));
	}

	private function securityErrorHandler(e:Event):void {
		dispatchEvent(new Event(ClassLoader.LOAD_ERROR));
	}
}

Submit Feedback

ActionScript 3.0 Language Reference	All Packages \| All Classes \| Language Elements \| Index \| Appendices \| Conventions \| Frames No Frames
Class ApplicationDomain	Properties \| Methods \| Examples

Package	flash.system
Class	public final class ApplicationDomain
Inheritance	ApplicationDomain Object